Beskrivelse

Licensering

Jeg, dette værks ophavsretsindehaver, publicerer hermed værket under den følgende licens:

Tilladelse er givet til at kopiere, distribuere og/eller ændre dette dokument under betingelserne i GNU Free Documentation License', Version 1.2 eller enhver senere version udgivet af Free Software Foundation; uden et invariant afsnit, ingen forsidetekster, og ingen bagsidetekst. En kopi af licensen er inkluderet i afsnittet GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Denne fil er udgivet under Creative Commons Kreditering-Del på samme vilkår 3.0 Ikke-porteret-licensen
	Du må frit: at dele – at kopiere, distribuere og overføre værket at remixe – at tilpasse værket Under følgende vilkår: kreditering – Du skal give passende kreditering, angive et link til licensen, og oplyse om der er foretaget ændringer. Du må gøre det på enhver fornuftig måde, men ikke på en måde der antyder at licensgiveren godkender dig eller din anvendelse. deling på samme vilkår – Hvis du bearbejder, ændrer eller bygger videre på dette værk, skal du distribuere dine bidrag under den samme eller en kompatibel licens som originalen.
	Denne licens blev tilføjet som en del af GFDL-licensopdateringen.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

POV-Ray code

Below is the code for rendering the above image using the Persistence of Vision Raytracer:

/*
================================================
Magnetic domain bubbles, "squeezed down" in size
------------------------------------------------
Created by Søren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/

#declare MagnetFont="arialbd.ttf" // Font for the "N" and "S" nomenclature on magnets
#declare NorthLtr="N";  // Letter to indicate north pole
#declare SouthLtr="S";  // Letter to indicate south pole

#declare MagLayerUp=pigment {  // Gradient with white
  gradient y                   // south pole side facing up
  color_map {
    [0.0 color rgb <1,0,0>]
    [1.0 color rgb <1,1,1>]
    }
  scale .000602
  translate -.000301
  }

#declare MagLayerDn=pigment {   // Gradient with red north
  gradient y                    // pole side facing up
  color_map {
    [0.0 color rgb <1,1,1>]
    [1.0 color rgb <1,0,0>]
    }
  scale .000602
  translate -.000301
  }

box {<-4,-.3,-4>,<4,.3,4> // The orthomagnetic sheet itself
  pigment {
    bumps         // "Random" pattern formed by the domains
    pigment_map {
      [0.0 MagLayerUp]  // A majority of 0.7 x 100% = 70% of the
      [0.7 MagLayerUp]  // surface has a south pole facing upwards, and
      [0.7 MagLayerDn]  // a minority of 0.3 x 100% = 30% of the surface
      [1.0 MagLayerDn]  // (the "bubbles") has north poles facing up.
      }
    scale <1,1000,1>  // Stretch so boundaries seem
    }                 // orthogonal to the surface
  finish {ambient .5} // Softens the self-shadows
  }

// Magnets to "squeeze" bubbles down in size:
box {<-4,3.5,-4>,<4,30,4> // The big north pole above the sheet
  pigment {
    object {
      text {ttf MagnetFont,NorthLtr,3,0 // with the letter for "north" on it
        scale 10 translate <-3,4,-30>
        }
      pigment {color rgbt <1,0,0,.9>}  // High degree of transparency (0.9)
      pigment {color rgbt <1,1,1,.9>}  // to hint that the field is weak
      }
    }
  finish {ambient .5}
  }

box {<-4,-79,-4>,<4,-4.5,4> // The big south pole below the sheet
  pigment {
    object {
      text {ttf MagnetFont,SouthLtr,3,0 // with the letter for "south" on it
        scale 10 translate <-3,-12,-30>
        }
      pigment {color rgbt <1,1,1,.9>}  // High degree of transparency (0.9)
      pigment {color rgbt <1,0,0,.9>}  // to hint that the field is weak
      }
    }
  finish {ambient .5}
  }

background {color rgb 1}  // White background

camera {  // View it all ...
  location <8,5,-10> // ... from this location
  look_at <0,0,0>     // ... looking towards this point
  up <0,4/3,0> right <1,0,0> // Force 4/3 "portrait" aspect ratio
  }

light_source {    // light source
  <-100,150,-120> // to illuminate
  color rgb 1     // the scene
  }