Bruger:Steenth/sparql: Forskelle mellem versioner

Fra Wikipedia, den frie encyklopædi
Gennemse historikken interaktivt
← Gå til forrige forskelGå til næste forskel →
Content deleted Content added
VisueltWikitekst
Linje 262: Linje 262:
SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}
}
}}

=== Analyse af [[:Kategori:Geomærkning savnes - andet land]] ===
{{SPARQL|query=
SELECT ?item ?itemLabel ?itemDescription ?landLabel {
OPTIONAL {
SERVICE wikibase:mwapi {
bd:serviceParam wikibase:api "Generator" .
bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
bd:serviceParam mwapi:gcmtitle "Kategori:Geomærkning savnes - andet land" .
bd:serviceParam mwapi:generator "categorymembers" .
bd:serviceParam mwapi:gcmtype "page" .
bd:serviceParam mwapi:gcmlimit "max" .
bd:serviceParam mwapi:gcmsort "timestamp" .
?item wikibase:apiOutputItem mwapi:item.
}
}
FILTER BOUND (?item)
?item wdt:P17 ?land .
SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000
}}
}}


Versionen fra 23. sep. 2021, 23:20

Eksempler på SPARQL forespørgelser

hovedstad

hovedstad for (P1376) mangler tilhørende hovedstad for (P1376) på danske enheder 

SELECT ?item ?itemLabel ?should_link_via_P1376_to ?should_link_via_P1376_toLabel 
WHERE
{
	?should_link_via_P1376_to wdt:P36 ?item .
	FILTER NOT EXISTS { ?item wdt:P1376 ?should_link_via_P1376_to } .
    ?item wdt:P17 wd:Q35 .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Kirker / sogne

sognid mangler

SELECT ?item ?itemLabel ?ophoer ?erstatafLabel ?digdag WHERE {
  ?item wdt:P31 wd:Q814648 .
  OPTIONAL { ?item wdt:P2290 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P576 ?ophoer }
  OPTIONAL { ?item wdt:P1366 ?erstataf }
  OPTIONAL { ?item wdt:P3614 ?digdag }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

kirker uden P5607 (sogn)

SELECT ?item ?itemLabel ?itemDescription ?stiftLabel ?admLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q16970 .
  OPTIONAL { ?item wdt:P5607 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P708 ?stift }
  OPTIONAL { ?item wdt:P131 ?adm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

kirker uden adresse

SELECT ?item ?itemLabel ?itemDescription ?stiftLabel ?admLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q16970 .
  OPTIONAL { ?item wdt:P6375 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P708 ?stift }
  OPTIONAL { ?item wdt:P131 ?adm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

sogne med erstattet af

SELECT ?item ?itemLabel ?itemDescription ?stiftLabel ?admLabel ?ophoer ?erstat_afLabel WHERE {
  ?item wdt:P31 wd:Q814648 .
  ?item wdt:P1366 ?erstat_af .
  OPTIONAL { ?item wdt:P708 ?stift }
  OPTIONAL { ?item wdt:P131 ?adm }
  OPTIONAL { ?item wdt:P576 ?ophoer }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

kirker uden P140/region eller P708/stift

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q16970 .
  OPTIONAL { ?item wdt:P140 ?region }
  FILTER(!bound(?region))
  OPTIONAL { ?item wdt:P708 ?stift }
  FILTER(!bound(?stift))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

kirker med P140/region

SELECT ?item ?itemLabel ?itemDescription ?regionLabel ?admLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q16970 .
  ?item wdt:P140 ?region .
  OPTIONAL { ?item wdt:P131 ?adm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

sogne med P361/del af

SELECT ?item ?itemLabel ?delafLabel ?stiftLabel ?digdag WHERE {
  ?item wdt:P31 wd:Q814648 .
  ?item wdt:P361 ?delaf .
  OPTIONAL { ?item wdt:P708 ?stift }
  OPTIONAL { ?item wdt:P3614 ?digdag }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Muligvis udskilte sogne

Tjekker om udskilt fra (P807). erstatter (P1365) og beskrevet i (P1343) Trap Danmark 3. udgave (Q80437693). Der nogle falske positive med kirker i købstæder og Sønderjylland... 

SELECT ?item ?itemLabel ?itemDescription ?stiftLabel ?admLabel ?etab ?ophoer ?erstat_afLabel ?sognenr ?digdag WHERE {
  VALUES ?sogne { wd:Q814648 wd:Q102854139 }
  ?item wdt:P31 ?sogne .
  OPTIONAL { ?item wdt:P807 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P1365 ?dummy1 }
  FILTER(!bound(?dummy1))
  FILTER NOT EXISTS {
      ?item wdt:P1343 wd:Q80437693
  }
  
  OPTIONAL { ?item wdt:P708 ?stift }
  OPTIONAL { ?item wdt:P131 ?adm }
  OPTIONAL { ?item wdt:P571 ?etab }
  OPTIONAL { ?item wdt:P576 ?ophoer }
  OPTIONAL { ?item wdt:P2290 ?sognenr }
  OPTIONAL { ?item wdt:P3614 ?digdag }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

p31 eller p279 mangler

p31 mangler, men koordinater findes

SELECT ?item ?itemLabel
WITH {
  SELECT ?item WHERE {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
    OPTIONAL { ?item wdt:P31 ?dummy0 }
    FILTER(!bound(?dummy0))
    OPTIONAL { ?item wdt:P279 ?dummy1 }
    FILTER(!bound(?dummy1))
    OPTIONAL { ?item wdt:P17 ?dummy2 }
    FILTER(!bound(?dummy2))
    OPTIONAL { ?item wdt:P373 ?dummy3 }
    FILTER(!bound(?dummy3))
    OPTIONAL { ?item wdt:P646 ?dummy4 }
    FILTER(!bound(?dummy4))
    ?item wdt:P625 ?koor
  }
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?antal)
LIMIT 250

Prøv det!

se også

p31 mangler, men hovedkategori findes

SELECT ?item ?itemLabel ?katLabel
WITH {
  SELECT ?item ?kat WHERE {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
    OPTIONAL { ?item wdt:P31 ?dummy0 }
    FILTER(!bound(?dummy0))
    OPTIONAL { ?item wdt:P279 ?dummy1 }
    FILTER(!bound(?dummy1))
    OPTIONAL { ?item wdt:P17 ?dummy2 }
    FILTER(!bound(?dummy2))
    OPTIONAL { ?item wdt:P373 ?dummy3 }
    FILTER(!bound(?dummy3))
    OPTIONAL { ?item wdt:P646 ?dummy4 }
    FILTER(!bound(?dummy4))
    ?item wdt:P910 ?kat
  }
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?antal)
LIMIT 250

Prøv det!

p31 mangler, men sport findes

SELECT ?item ?itemLabel ?sportLabel
WITH {
  SELECT ?item ?sport WHERE {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
    OPTIONAL { ?item wdt:P31 ?dummy0 }
    FILTER(!bound(?dummy0))
    OPTIONAL { ?item wdt:P279 ?dummy1 }
    FILTER(!bound(?dummy1))
    OPTIONAL { ?item wdt:P17 ?dummy2 }
    FILTER(!bound(?dummy2))
    OPTIONAL { ?item wdt:P373 ?dummy3 }
    FILTER(!bound(?dummy3))
    OPTIONAL { ?item wdt:P646 ?dummy4 }
    FILTER(!bound(?dummy4))
    ?item wdt:P641 ?sport
  }
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?antal)
LIMIT 250

Prøv det!

museum uden land på dawiki

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q33506 .
  OPTIONAL { ?item wdt:P17 ?dummy0 }
  FILTER(!bound(?dummy0))
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

dansk museum uden p131

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q33506 .
  OPTIONAL { ?item wdt:P131 ?dummy0 }
  FILTER(!bound(?dummy0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Geografi

til p131 mangler p17

SELECT ?item ?itemLabel ?stedLabel WHERE {
  ?item wdt:P131 ?sted .
  OPTIONAL { ?item wdt:P17 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P495 ?dummy1 }
  FILTER(!bound(?dummy1))
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Landsby uden bykode

SELECT ?item ?itemLabel ?kmdLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q532 .
  OPTIONAL { ?item wdt:P1894 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P131 ?kmd }
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Analyse af Kategori:Geomærkning savnes - andet land

SELECT ?item ?itemLabel ?itemDescription ?landLabel {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Geomærkning savnes - andet land" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  ?item wdt:P17 ?land .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000

Prøv det!

Analyse af Kategori:Geomærkning savnes - hovedkvarter i Danmark

SELECT ?item ?itemLabel ?itemDescription ?byLabel {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Geomærkning savnes - hovedkvarter i Danmark" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  ?item wdt:P159 ?by .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000

Prøv det!

Analyse af Kategori:Geomærkning savnes - Danmark - anden kommune

SELECT ?item ?itemLabel ?itemDescription ?kommuneLabel {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Geomærkning savnes - Danmark - anden kommune" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  ?item wdt:P131 ?kommune .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000

Prøv det!

tjek impot af geografiske koordinater

tjek af p31 - wikimedia-kategorier

SELECT ?item ?itemLabel ?property ?propertyLabel ?value ?valueLabel
WHERE
{
	{
		SELECT DISTINCT ?item ?property ?value {
			?item wdt:P625 [] .
			VALUES ?value { wd:Q4167836 wd:Q11266439 wd:Q13406463 wd:Q4167410 wd:Q14204246 } .
			?item wdt:P31 ?value .
			BIND( wd:P31 AS ?property ) .
            ?wiki0 <http://schema.org/about> ?item .
            ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
		} LIMIT 100
	} .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

tjek af p31 - selskaber, virksomheder, mennesker

SELECT ?item ?itemLabel ?property ?propertyLabel ?value ?valueLabel
WHERE
{
	{
		SELECT DISTINCT ?item ?property ?value {
			?item wdt:P625 [] .
			VALUES ?value { wd:Q5 wd:Q783794 wd:Q4830453 } .
			?item wdt:P31 ?value .
			BIND( wd:P31 AS ?property ) .
            ?wiki0 <http://schema.org/about> ?item .
            ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
		} LIMIT 100
	} .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

undergrupper

SELECT ?item ?itemLabel ?property ?propertyLabel ?value ?valueLabel
WHERE
{
	{
		SELECT DISTINCT ?item ?property ?value {
			?item wdt:P625 []; wdt:P279 ?value .
			BIND( wd:P279 AS ?property ) .
            ?wiki0 <http://schema.org/about> ?item .
            ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
		} LIMIT 100
	} .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

folketingsmedlemmer

folketingsmedlemmer uden artikel

SELECT ?item ?itemLabel ?partiLabel ?statLabel ?koenLabel (GROUP_CONCAT( DISTINCT ?sitelink) as ?links) 
WHERE {
  ?item wdt:P39 wd:Q12311817 .
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  OPTIONAL { ?item wdt:P102 ?parti }
  OPTIONAL { ?item wdt:P27 ?stat }
  OPTIONAL { ?item wdt:P21 ?koen }
  OPTIONAL { ?s schema:about ?item ; schema:inLanguage ?lang . BIND(CONCAT("[", str(?s), " ", ?lang, "]") as ?sitelink)  } 
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
GROUP BY ?item ?itemLabel ?partiLabel ?statLabel ?koenLabel

Prøv det!

Folketingsmedlemmer 2015-2019

SELECT ?item ?itemLabel ?groupLabel ?districtLabel ?start 
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q12311817 ; pq:P2937 wd:Q29093888 .
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?end }
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P768 ?district }
    FILTER(!BOUND(?end) || ?end > NOW())
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Folketingsmedlemmer 2019-

SELECT ?item ?itemLabel ?groupLabel ?districtLabel ?start 
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q12311817 ; pq:P2937 wd:Q63487103 .
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?end }
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P768 ?district }
    FILTER(!BOUND(?end) || ?end > NOW())
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Er medlem af politisk parti (P102) sat

SELECT ?item ?itemLabel ?groupLabel ?districtLabel ?start ?perLabel
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q12311817 .
    ?ps pq:P2937 ?per .
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?end }
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P768 ?district }
    OPTIONAL { ?item wdt:P102 ?parti }
    FILTER(!bound(?parti))
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Tjek venstre-folk

SELECT ?item ?itemLabel ?groupLabel ?districtLabel ?samlingLabel
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q12311817 ; pq:P4100 wd:Q500190 .
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P768 ?district }
    OPTIONAL { ?ps pq:P2739 ?samling }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

PACE medlemsid

Tjek danskere med PACE medlemsid (P1331), som ikke har embede folketingsmedlem 

SELECT ?item ?itemLabel ?embedeLabel
WHERE {
  ?item wdt:P1331 ?id .
  ?item wdt:P27 wd:Q35 .
  FILTER NOT EXISTS { ?item wdt:P39 wd:Q12311817 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Folketingsmedlemmer uden egenskab ft.dk henvisning

Tjek folketingsmedlemmer uden ft.dk politiker-ID (P7882) 

SELECT ?item ?itemLabel ?groupLabel ?districtLabel ?start ?perLabel
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q12311817 .
    ?ps pq:P2937 ?per .
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?end }
    ?ps pq:P4100 ?group .
    OPTIONAL { ?ps pq:P768 ?district }
    OPTIONAL { ?item wdt:P7882 ?ftdk_link }
    FILTER(!bound(?ftdk_link))
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Europaparlament

ottende europaparlament valgt i Danmark

Valg i 2015 

SELECT ?item ?itemLabel ?repraensLabel ?groupLabel ?districtLabel ?start ?slut ?erstaterLabel ?erstatesafLabel
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q27169 ; pq:P2937 wd:Q17315694; pq:P768 wd:Q5257930 .
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?end }
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P1268 ?repraens }
    OPTIONAL { ?ps pq:P768 ?district }
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?slut }
    OPTIONAL { ?ps pq:P1365 ?erstater }
    OPTIONAL { ?ps pq:P1366 ?erstatesaf }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

niende europaparlament valgt i Danmark

Valg i 2019 

SELECT ?item ?itemLabel ?repraensLabel ?groupLabel ?districtLabel ?start ?slut ?erstaterLabel ?erstatesafLabel
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q27169 ; pq:P2937 wd:Q64038205; pq:P768 wd:Q5257930 .
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?end }
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P1268 ?repraens }
    OPTIONAL { ?ps pq:P768 ?district }
    OPTIONAL { ?ps pq:P580 ?start }
    OPTIONAL { ?ps pq:P582 ?slut }
    OPTIONAL { ?ps pq:P1365 ?erstater }
    OPTIONAL { ?ps pq:P1366 ?erstatesaf }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

europaparlamentsmedlemmer uden artikel

SELECT ?item ?itemLabel ?represLabel ?groupLabel ?districtLabel ?samlingLabel
  WHERE { 
    ?item p:P39 ?ps . 
    ?ps ps:P39 wd:Q27169 ; pq:P768 wd:Q5257930 .
    OPTIONAL { ?ps pq:P1268 ?repres }
    OPTIONAL { ?ps pq:P4100 ?group }
    OPTIONAL { ?ps pq:P768 ?district }
    OPTIONAL { ?ps pq:P2937 ?samling }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
    OPTIONAL {
      ?wiki0 <http://schema.org/about> ?item .
      ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
    }
    FILTER(!bound(?wiki0))
}

Prøv det!

Litteratur

danske digtere uden artikel på dawiki

SELECT ?item ?itemLabel ?foedt ?doed WHERE {
  ?item wdt:P27 wd:Q35 .
  ?item wdt:P106 wd:Q49757 .
  OPTIONAL { ?item wdt:P569 ?foedt }
  OPTIONAL { ?item wdt:P570 ?doed }
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en,ru" } .
}

Prøv det!

Modtagere af Michael Strunge-Prisen (Q62060295)

SELECT ?item ?itemLabel ?tid
  WHERE { 
    ?item p:P166 ?ps . 
    ?ps ps:P166 wd:Q62060295 .
    OPTIONAL { ?ps pq:P585 ?tid }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
ORDER BY ?tid

Prøv det!

Danske litteraturpriser

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q378427 .
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Areal på kommuner

SELECT ?item ?itemLabel ?areal WHERE {
  ?item wdt:P31 wd:Q2177636 .
  OPTIONAL { ?item wdt:P2046 ?areal }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Wikimedia-liste

SELECT ?item ?itemLabel ?overLabel ?landLabel WHERE {
  ?item wdt:P31 wd:Q13406463 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  OPTIONAL { ?item wdt:P360 ?over }
  OPTIONAL { ?item wdt:P17 ?land }
  FILTER(!bound(?dummy0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Samlinger

SMK

SELECT ?item ?itemLabel ?skaberLabel ?inventarnummer ?billeder ?commonscat ?kid WHERE {
  ?item wdt:P195 wd:Q671384 .
  OPTIONAL { ?item wdt:P217 ?inventarnummer }
  OPTIONAL { ?item wdt:P170 ?skaber }
  OPTIONAL { ?item wdt:P18 ?billeder }
  OPTIONAL { ?item wdt:P373 ?commonscat }
  OPTIONAL { ?item wdt:P2108 ?kid }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Nivaagaard

SELECT ?item ?itemLabel ?skaberLabel ?inventarnummer ?billeder ?commonscat WHERE {
  ?item wdt:P195 wd:Q10601378 .
  OPTIONAL { ?item wdt:P217 ?inventarnummer }
  OPTIONAL { ?item wdt:P170 ?skaber }
  OPTIONAL { ?item wdt:P18 ?billeder }
  OPTIONAL { ?item wdt:P373 ?commonscat }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Eksemple på katalog

SELECT ?item ?itemLabel ?id ?samlingLabel
  WHERE { 
    ?item p:P528 ?ps .
    ?ps pq:P972 wd:Q22344483 .
    ?ps ps:P528 ?id .
    OPTIONAL { ?item wdt:P195 ?samling }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Kunstnere i den samling - her SMK

SELECT ?item ?itemLabel ?kid ?commons_skab ?commonscat WHERE {
  ?item wdt:P6379 wd:Q671384 .
  OPTIONAL { ?item wdt:P1138 ?kid }
  OPTIONAL { ?item wdt:P1472 ?commons_skab }
  OPTIONAL { ?item wdt:P373 ?commonscat }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

p131 = København

SELECT ?item ?itemLabel ?landLabel ?typeLabel WHERE {
  ?item wdt:P131 wd:Q1748 .
  OPTIONAL { ?item wdt:P17 ?land }
  OPTIONAL { ?item wdt:P31 ?type }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Biblioteker

SELECT ?item ?isil ?itemLabel ?admLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P31 wd:Q2326815 .
  OPTIONAL { ?item wdt:P131 ?adm }
  OPTIONAL { ?item wdt:P791 ?isil }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Findes på enwiki ikke dawiki uden p31

SELECT ?item ?itemLabel ?admLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  OPTIONAL { ?item wdt:P31 ?dummy0 }
  FILTER(!bound(?dummy0))
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://en.wikipedia.org/> .
  OPTIONAL {
    ?wiki1 <http://schema.org/about> ?item .
    ?wiki1 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki1))
  OPTIONAL { ?item wdt:P131 ?adm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } 
}

Prøv det!

malerier med p131

SELECT ?item ?itemLabel ?landLabel ?admLabel ?placeringLabel ?samlingLabel WHERE {
  ?item wdt:P31 wd:Q3305213 .
  ?item wdt:P131 ?adm .
  OPTIONAL { ?item wdt:P17 ?land }
  OPTIONAL { ?item wdt:P276 ?placering }
  OPTIONAL { ?item wdt:P195 ?samling }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}
ORDER BY ?landLabel ?admLabel ?samlingLabel ?itemLabel

Prøv det!

mennesker

mennesker med kun p31:q5

SELECT ?item ?itemLabel  WHERE {
  ?item wdt:P31 wd:Q5 ; wikibase:statements 1 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

køn mangler

SELECT ?item ?itemLabel ?page_titleDA
WHERE {
  ?item wdt:P31 wd:Q5 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  OPTIONAL { ?item wdt:P21 ?koen }
  FILTER(!bound(?koen)) 
  ?article schema:about ?item ; schema:isPartOf <https://da.wikipedia.org/> ;  schema:name ?page_titleDA .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Optæl køn

SELECT ?antal ?koen ?koenLabel 
WITH {
  SELECT ?koen (COUNT(*) AS ?antal) WHERE {
    ?item wdt:P31 wd:Q5 .
    ?item wdt:P21 ?koen .
    ?article schema:about ?item.
    ?article schema:isPartOf <https://da.wikipedia.org/>
  }
  GROUP BY ?koen
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?antal)
LIMIT 25

Prøv det!

Optæl køn på danskere

SELECT ?antal ?koen ?koenLabel 
WITH {
  SELECT ?koen (COUNT(*) AS ?antal) WHERE {
    ?item wdt:P31 wd:Q5 .
    ?item wdt:P21 ?koen .
    ?item wdt:P27 wd:Q35 .
    ?article schema:about ?item.
    ?article schema:isPartOf <https://da.wikipedia.org/>
  }
  GROUP BY ?koen
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?antal)
LIMIT 25

Prøv det!

Øvrige køn

SELECT ?item ?itemLabel ?itemDescription ?koenLabel
WHERE {
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P21 ?koen .
  ?article schema:about ?item.
  ?article schema:isPartOf <https://da.wikipedia.org/> .
  FILTER NOT EXISTS { ?item wdt:P21 wd:Q6581097 } .
  FILTER NOT EXISTS { ?item wdt:P21 wd:Q6581072 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}

Prøv det!

organisationer med både p157 og p131

SELECT ?item ?itemLabel ?typeLabel ?landLabel ?hovedkvarLabel ?admLabel WHERE {
  ?item wdt:P131 ?adm .
  ?item wdt:P159 ?hovedkvar .
  OPTIONAL { ?item wdt:P17 ?land }
  OPTIONAL { ?item wdt:P31 ?type }
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Kun danmark

SELECT ?item ?itemLabel ?typeLabel ?hovedkvarLabel ?admLabel WHERE {
  ?item wdt:P131 ?adm .
  ?item wdt:P159 ?hovedkvar .
  ?item wdt:P17 wd:Q35 .
  OPTIONAL { ?item wdt:P31 ?type }
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

danske emner uden dansk label

SELECT ?item ?itemLabel ?itemDescription WHERE {
 ?item wdt:P17 wd:Q35.     # Danmark

 SERVICE wikibase:label { bd:serviceParam wikibase:language "sv,no,nb,nn,en,de,pl,nl,fr,it,es,pt,fi,sl,sr,cs,ca". }
 FILTER(NOT EXISTS {
   ?item rdfs:label ?lang_label.
   FILTER(LANG(?lang_label) = "da") # med manglede tysk label
 })
}
ORDER BY ?itemLabel

Prøv det!

dansk objekt med hovedkvarter

SELECT ?item ?itemLabel ?hovedkvarLabel ?admLabel WHERE {
  ?item wdt:P17 wd:Q35 .
  ?item wdt:P159 ?hovedkvar .
  OPTIONAL { ?hovedkvar wdt:P131 ?adm }
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

geonames-kode uden dansk label

SELECT ?item ?itemLabel ?itemDescription ?geonamecode WHERE {
 ?item wdt:P2452 ?geonamecode .

 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de". }
 FILTER(NOT EXISTS {
   ?item rdfs:label ?lang_label.
   FILTER(LANG(?lang_label) = "da") # med manglede dansk label
 })
}
ORDER BY ?geonamecode

Prøv det!

Film

medvirkende i danskefilm.dk uden id

SELECT ?film ?dfi_film ?dk_filmid ?filmLabel ?item ?itemLabel ?dfi_person
WHERE {
  OPTIONAL { ?film wdt:P1804 ?dfi_film }
  ?film wdt:P3785 ?dk_filmid .
  ?film wdt:P495 wd:Q35 .
  ?film wdt:P161 ?item .
  OPTIONAL { ?item wdt:P3786 ?dk_personid }
  FILTER(!bound(?dk_personid))
  OPTIONAL { ?item wdt:P2626 ?dfi_person }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
ORDER BY ?filmid ?itemLabel

Prøv det!

medvirkende i danskefilm.dk uden filmdatabase-id

SELECT ?film ?dfi_film ?dk_filmid ?filmLabel ?dk_personid ?item ?itemLabel
WHERE {
  OPTIONAL { ?film wdt:P1804 ?dfi_film }
  ?film wdt:P3785 ?dk_filmid .
  ?film wdt:P495 wd:Q35 .
  ?film wdt:P161 ?item .
  OPTIONAL { ?item wdt:P3786 ?dk_personid }
  OPTIONAL { ?item wdt:P2626 ?dfi_person }
  FILTER(!bound(?dfi_person))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
ORDER BY ?dfi_film ?itemLabel

Prøv det!

personer i filmbase uden imdb med i film med imdb

SELECT ?film ?dfiid ?imdb ?filmLabel ?dkfilmid ?item ?itemLabel
WHERE {
  ?item wdt:P2626 ?dkfilmid .
  OPTIONAL { ?item wdt:P345 ?personid }
  FILTER(!bound(?personid))
  ?film wdt:P1804 ?dfiid .
  ?film wdt:P345 ?imdb .
  ?film wdt:P161 ?item .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
ORDER BY ?filmid ?itemLabel

Prøv det!


medvirkende i danskfilmogtv.dk uden id

SELECT ?film ?dfi_film ?dk_filmid ?filmLabel ?item ?itemLabel ?dfi_person ?dkfilm_person
WHERE {
  OPTIONAL { ?film wdt:P1804 ?dfi_film }
  ?film wdt:P4209 ?dk_filmid .
  ?film wdt:P161 ?item .
  OPTIONAL { ?item wdt:P4112 ?dk_personid }
  FILTER(!bound(?dk_personid))
  OPTIONAL { ?item wdt:P2626 ?dfi_person }
  OPTIONAL { ?item wdt:P3786 ?dkfilm_person }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
ORDER BY ?filmid ?itemLabel

Prøv det!

film med vurdering fra Medierådet uden filmdatabase-id

SELECT ?item ?value ?itemLabel
WHERE {
  ?item wdt:P5970 ?value .
  OPTIONAL { ?item wdt:P1804 ?dfi_id }
  FILTER(!bound(?dfi_id))
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en,sv,de" }
}

Prøv det!

serie-afsnit borgen uden danskfilmogtv

SELECT ?item ?itemLabel ?imdb WHERE {
  ?item wdt:P179 wd:Q250111 .
  OPTIONAL { ?item wdt:P345 ?imdb }
  OPTIONAL { ?item wdt:P4209 ?danskfilmogtv }
  FILTER(!bound(?danskfilmogtv))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Den danske filmskole uden danskfilmogtv (filmklippere)

SELECT ?item ?itemLabel ?slut
  WHERE { 
    ?item p:P69 ?ps . 
    ?ps ps:P69 wd:Q936354 ; pq:P812 wd:Q7042855 .
  OPTIONAL { ?ps pq:P582 ?slut }
  OPTIONAL { ?item wdt:P4112 ?id }
  FILTER(!bound(?id))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

P.S. Krøyer, 23. JULI 1851 - 20. NOVEMBER 1909, fortegnelse af hans oliemalerie

SELECT ?item ?value ?itemLabel ?picture ?samlingLabel ?placeringLabel
    WHERE{
      ?item p:P528 ?statement .
      ?statement pq:P972 wd:Q22811181 .
      ?statement ps:P528 ?value .
      OPTIONAL { ?item wdt:P18 ?picture }
      OPTIONAL { ?item wdt:P195 ?samling }
      OPTIONAL { ?item wdt:P276 ?placering }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

DBU's landsholdsdatabase - spillere

SELECT ?item ?itemLabel ?value ?page_titleDA
WHERE {
  ?item wdt:P6109 ?value .
  ?article schema:about ?item ; schema:isPartOf <https://da.wikipedia.org/> ;  schema:name ?page_titleDA .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}

Prøv det!

Kvinde projekter

Tjek DKL som mangler beskæftigelse og fødselsdato

SELECT ?item ?itemLabel ?url
WHERE {
  ?item p:P1343 ?ps .
  ?ps ps:P1343 wd:Q259197  .
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  OPTIONAL { ?ps pq:P2699 ?url }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
  OPTIONAL { ?item wdt:P27 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P569 ?dummy1 }
  FILTER(!bound(?dummy1))
  OPTIONAL { ?item wdt:P570 ?dummy2 }
  FILTER(!bound(?dummy2))
}

Prøv det!

Tjek DKL som mangler beskæftigelse og statsborgerskab

SELECT ?item ?itemLabel ?itemDescription ?foedt ?doed ?url
WHERE {
  ?item p:P1343 ?ps .
  ?ps ps:P1343 wd:Q259197  .
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  ?item wdt:P569 ?foedt .
  OPTIONAL { ?item wdt:P570 ?doed }
  OPTIONAL { ?ps pq:P2699 ?url }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
  OPTIONAL { ?item wdt:P27 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P106 ?dummy1 }
  FILTER(!bound(?dummy1))
}

Prøv det!

DKL uden P7939

SELECT ?item ?itemLabel ?url
WHERE {
  ?item p:P1343 ?ps .
  ?ps ps:P1343 wd:Q259197  .
  OPTIONAL { ?ps pq:P2699 ?url }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
  OPTIONAL { ?item wdt:P7939 ?dummy0 }
  FILTER(!bound(?dummy0))
}

Prøv det!

Oprettet på arbejdsliste

SELECT ?item ?itemLabel ?tid WHERE {
  ?item p:P5008 ?ps .
  ?ps ps:P5008 wd:Q67147253  .
  OPTIONAL { ?ps pq:P585 ?tid }
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Arbejdsliste uden beskæftigelse, født- og evt dødsår

Tjek af Wikipedia:WikiProjekt Kvinder/lister/arbejdsliste kønsgab artikel mangler 

SELECT ?item ?itemLabel ?itemDescription
WHERE {
  ?item wdt:P5008 wd:Q67147253 .
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki0))
  OPTIONAL { ?item wdt:P27 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P569 ?dummy1 }
  FILTER(!bound(?dummy1))
  OPTIONAL { ?item wdt:P570 ?dummy2 }
  FILTER(!bound(?dummy2))
  OPTIONAL { ?item wdt:P106 ?dummy3 }
  FILTER(!bound(?dummy3))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}

Prøv det!

Både på arbejdsliste og DKL

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P1343 wd:Q259197  .
  ?item wdt:P5008 wd:Q67147253 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Emne med DKL mangler dansk label

SELECT ?item ?itemLabel ?itemDescription WHERE {
 ?item wdt:P1343 wd:Q259197  .

 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,no,sv,de". }
 FILTER(NOT EXISTS {
   ?item rdfs:label ?lang_label.
   FILTER(LANG(?lang_label) = "da") #with missing Italian label
 })
}
ORDER BY ?itemLabel

Prøv det!

Optælling af personer efter køn på dawiki

SELECT ?count ?gender ?genderLabel 
WITH {
  SELECT ?gender (COUNT(*) AS ?count) WHERE {
    ?item wdt:P31 wd:Q5 .
    ?item wdt:P21 ?gender .
    ?article schema:about ?item.
    ?article schema:isPartOf <https://da.wikipedia.org/>
  }
  GROUP BY ?gender
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?count)
LIMIT 25

Prøv det!

Eesti 1000

danske artikler på eesti 1000 listen

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P5008 wd:Q57005414 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

danske artikel mangler fra emne på eesti 1000 listen

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P5008 wd:Q57005414 .
  OPTIONAL {
     ?wiki0 <http://schema.org/about> ?item .
     ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Tjek medlemmer af sportshold

tjek kategori indeholder (P4224) kvalifikatorer

Tjek indhold af kategori indeholder (P4224) 

SELECT ?klub ?klubLabel ?klubcat ?klubcatLabel ?klubspilLabel ?beskaeffelseLabel
  WHERE {
    ?klub wdt:P6112 ?klubcat .
    ?klubcat p:P4224 ?ps . 
    ?ps ps:P4224 wd:Q5 .
    OPTIONAL { ?ps pq:P54 ?klubspil }
    OPTIONAL { ?ps pq:P106 ?beskaeffelse }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en,it,es" }
}

Prøv det!

P6112 mangler

SELECT ?klubcat ?klubcatLabel ?klubkodeLabel
  WHERE {
    ?klubcat wdt:P971 ?klubkode .
    VALUES ?klubkode { wd:Q58840094 wd:Q56465024 wd:Q63349282 }
    FILTER NOT EXISTS {
      ?klub wdt:P6112 ?klubcat
    }
    ?wiki0 <http://schema.org/about> ?klubcat .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Tjek af sportssæson

Tjek ud fra en liga

Tjek ud fra tidsperiode (P2348) 

SELECT ?item ?itemLabel ?forrigeLabel ?naesteLabel ?forrigexLabel ?ligaLabel WHERE {
  ?item wdt:P2348 wd:Q53386161 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  ?item wdt:P3450 ?liga .
  ?item p:P3450 ?ps .
  OPTIONAL { ?ps pq:P155 ?forrige }
  OPTIONAL { ?ps pq:P156 ?naeste }
  OPTIONAL { ?item wdt:P155 ?forrigex }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Tjek en liga-sæson

Tjek ud fra sportssæson af (P3450) 

SELECT ?item ?itemLabel ?forrigeLabel ?naesteLabel ?forrigexLabel ?perLabel WHERE {
  ?item wdt:P3450 wd:Q912431 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  OPTIONAL { ?item wdt:P2348 ?per }
  ?item p:P3450 ?ps .
  OPTIONAL { ?ps pq:P155 ?forrige }
  OPTIONAL { ?ps pq:P156 ?naeste }
  OPTIONAL { ?item wdt:P155 ?forrigex }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Tjek en klub-sæson

Tjek ud fra sæson for klub eller hold (P5138) 

SELECT ?item ?itemLabel ?forrigeLabel ?naesteLabel ?forrigexLabel ?naestexLabel ?perLabel WHERE {
  ?item wdt:P5138 wd:Q635654 .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  OPTIONAL { ?item wdt:P2348 ?per }
  ?item p:P5138 ?ps .
  OPTIONAL { ?ps pq:P155 ?forrige }
  OPTIONAL { ?ps pq:P156 ?naeste }
  OPTIONAL { ?item wdt:P155 ?forrigex }
  OPTIONAL { ?item wdt:P156 ?naestex }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Færøerne

beliggende i det administrative område (P131) = Færøerne (Q4628) 

#defaultView:Map
SELECT ?item ?itemLabel ?geo WHERE {
  ?item wdt:P131 wd:Q4628;
        wdt:P625 ?geo .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,sv,en" }
}

Prøv det!

Mangler begivenhed

#defaultView:Map
SELECT ?item ?itemLabel ?geo WHERE {
  ?item wdt:P17 wd:Q4628 .
  OPTIONAL { ?item wdt:P706 ?begiv }
  FILTER(!bound(?begiv))
  ?item wdt:P131 ?kmd;
        wdt:P625 ?geo .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,sv,en" }
}

Prøv det!

Kirkegård

Find a Grave kirkegård

SELECT ?landLabel ?item ?itemLabel ?itemDescription ?id WHERE {
  ?item wdt:P2025 ?id .
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  OPTIONAL { ?item wdt:P17 ?land }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Gravsted.dk uden dødsdato

SELECT ?item ?itemLabel ?id
WHERE {
  ?item wdt:P4359 ?id .
  OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
  OPTIONAL { ?item wdt:P570 ?dummy2 }
  FILTER(!bound(?dummy2))
}

Prøv det!

Personer fra

Artikler med kategori for tilknyttede personer (P1792)

Relevant for dawiki

SELECT ?item ?itemLabel ?kategoriLabel WITH {
  SELECT ?item ?kategori
  WHERE {
    ?item wdt:P1792 ?kategori .
    ?wiki0 <http://schema.org/about> ?kategori .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'da, en' }
}

Prøv det!

Mangler P1792

SELECT ?item ?itemLabel
  WHERE {
    ?item wdt:P971 wd:Q19660746 .
    FILTER NOT EXISTS {
      ?person_sted wdt:P1792 ?item
    }
    ?wiki0 <http://schema.org/about> ?item .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
ORDER BY ?itemLabel

Prøv det!

Tjek danske kommuner

SELECT ?kommune ?kommuneLabel ?kat ?katLabel ?foedt ?foedtLabel
  WHERE {
    ?kommune wdt:P31 wd:Q2177636 .
    OPTIONAL { ?kommune wdt:P1792 ?kat }
    OPTIONAL { ?kommune wdt:P1464 ?foedt }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Danske kommuner uden personer fra

SELECT ?kommune ?kommuneLabel ?kat ?katLabel ?foedt ?foedtLabel
  WHERE {
    ?kommune wdt:P31 wd:Q2177636 .
    ?kommune wdt:P1792 ?kat .
    OPTIONAL { ?kommune wdt:P1464 ?foedt }
    OPTIONAL {
      ?wiki0 <http://schema.org/about> ?kat .
      ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/>
    }
    FILTER(!bound(?wiki0))
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Tjek af kategori for personer, der er født dette sted (P1464)

SELECT ?item ?itemLabel ?foedtkat ?foedtkatLabel ?stedkat ?stedkatLabel WITH {
  SELECT ?item ?foedtkat ?stedkat
  WHERE {
    ?item wdt:P1464 ?foedtkat .
    OPTIONAL { ?item wdt:P1792 ?stedkat }
    ?wiki0 <http://schema.org/about> ?foedtkat .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'da, en' }
}

Prøv det!

Tjek danske steder med både P1464 og P1792

SELECT ?item ?itemLabel ?foedtkat ?foedtkatLabel ?stedkat ?stedkatLabel WITH {
  SELECT ?item ?foedtkat ?stedkat
  WHERE {
    ?item wdt:P1464 ?foedtkat .
    ?item wdt:P1792 ?stedkat .
    ?item wdt:P17 wd:Q35 .
    ?wiki0 <http://schema.org/about> ?stedkat .
    ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'da, en' }
}

Prøv det!

Kraks Blå Bog

Personer uden artikel

SELECT ?item ?itemLabel ?itemDescription ?aargang WHERE {
  ?item wdt:P1343 wd:Q300908 .
  ?item p:P1343 ?ps .
  ?ps ps:P1343 wd:Q300908 .
  OPTIONAL { ?ps pq:P478 ?aargang }
  OPTIONAL {
     ?wiki0 <http://schema.org/about> ?item .
     ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  }
  FILTER(!bound(?wiki0))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

Nye i 2020

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item p:P1343 ?ps .
  ?ps ps:P1343 wd:Q300908 .
  ?ps pq:P478 "2020/21" .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
}

Prøv det!

danske twitter brugere

SELECT ?item ?itemLabel ?itemDescription ?konto ?antal 
  WHERE {
    ?item wdt:P27 wd:Q35 .
    ?item wdt:P2002 ?konto .
    ?item p:P2002 ?ps . 
    ?ps pq:P3744 ?antal
    SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}

Prøv det!

Tjk FD

Antal forespørgsler som tjekker output fra {{FD}}

Kategori:Wikidata mangler en fødselsdato

SELECT ?item ?itemLabel ?itemDescription ?typeLabel {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Wikidata mangler en fødselsdato" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  OPTIONAL { ?item wdt:P31 ?type }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000

Prøv det!

Kategori:Wikidata mangler en dødsdato

SELECT ?item ?itemLabel ?itemDescription ?typeLabel {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Wikidata mangler en dødsdato" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  OPTIONAL { ?item wdt:P31 ?type }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000

Prøv det!

Kategori:Wikidata mangler køn

SELECT ?item ?itemLabel ?itemDescription ?typeLabel {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Wikidata mangler køn" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  OPTIONAL { ?item wdt:P31 ?type }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 1000

Prøv det!

Kategori:Wikidata har en fødselsdato

SELECT ?item ?itemLabel ?itemDescription ?foedt ?doed {
  OPTIONAL {
    SERVICE wikibase:mwapi {
	 bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Wikidata har en fødselsdato" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      bd:serviceParam mwapi:gcmsort "timestamp" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
  FILTER BOUND (?item)
  OPTIONAL { ?item wdt:P569 ?foedt }
  OPTIONAL { ?item wdt:P570 ?doed }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" } .
} limit 5000

Prøv det!

Øvrige tjek af person-artikler

Wikidata mangler fornavn - danskere

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?wiki0 <http://schema.org/about> ?item .
  ?wiki0 <http://schema.org/isPartOf> <https://da.wikipedia.org/> .
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P27 wd:Q35 .
  OPTIONAL { ?item wdt:P735 ?fornavn }
  FILTER(!bound(?fornavn))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" }
}
LIMIT 8000

Prøv det!

DBL

SELECT ?item ?itemLabel ?itemDescription
WHERE {
  ?item wdt:P8341 ?id .
  ?item wdt:P31 wd:Q5 .
  OPTIONAL { ?item wdt:P27 ?dummy0 }
  FILTER(!bound(?dummy0))
  OPTIONAL { ?item wdt:P569 ?dummy1 }
  FILTER(!bound(?dummy1))
  OPTIONAL { ?item wdt:P570 ?dummy2 }
  FILTER(!bound(?dummy2))
  OPTIONAL { ?item wdt:P106 ?dummy3 }
  FILTER(!bound(?dummy3))
  OPTIONAL { ?item wdt:P21 ?dummy4 }
  FILTER(!bound(?dummy4))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}

Prøv det!

Den store danske i Wikidata

Hentet fra d:Wikidata:Project chat/Archive/2021/09#Is there a way to find out how many times a specific website is referenced on Wikidata? 

SELECT DISTINCT ?item ?itemLabel 
WHERE {
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "denstoredanske.dk".
    ?item wikibase:apiOutputItem mwapi:title .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Prøv det!

Den store danske - beskrevet i og url'er

SELECT ?item ?itemLabel ?id ?url ?refurl
WHERE {
  ?item p:P1343 ?ps .
  ?ps ps:P1343 wd:Q1186818  .
  OPTIONAL { ?ps pq:P2699 ?url }
  OPTIONAL { ?ps pq:P854 ?refurl }
  OPTIONAL { ?item wdt:P8313 ?id }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}

Prøv det!

Hentet fra "https://da.wikipedia.org/w/index.php?title=Bruger:Steenth/sparql&oldid=10868337"