Bruger:Dipsacus fullonum

Fra Wikipedia, den frie encyklopædi
Karteboller

Mit brugernavn, Dipsacus fullonum, er det videnskabelige navn for planten gærdekartebolle. Jeg valgte det internationale videnskabelige navn fordi kontoen også bruges på Wikimedia-projekter som ikke er dansksprogede. På dansk i min signatur bruger jeg også det mere mundrette Kartebolle.

Jeg har været bruger på dansk Wikipedia i perioder siden 2004. I starten brugte jeg et andet brugernavn som måske kunne hjælpe med til at identificere mig. For at undgå dette oprettede jeg det nuværende brugernavn i 2014. Jeg beder venligst brugere som kender mit gamle brugernavn, om ikke offentliggøre hvad det er.

Tildelte stjerner, kager og medaljer[redigér | rediger kildetekst]

Arbejdsplan[redigér | rediger kildetekst]

  • Oprettelse af de manglende tidszone-artikler (linkene i {{Navboks tidszoner}} herunder) og opdatering af de eksisterende tidszone-artikler. Vil erstatte fast bredde på tidszonekortene (300px) med 2 gange standardbredden for thumbnails (upright=2) jf. anbefalingen i Stilmanualen. For brugere som ikke har ændret i deres standardindstillinger, er standardbredden for thumbnails 220px. De vil derfor se noget større kort som følge af ændringen.
  • Artikler for fodens knogler (linkene i {{Fodens knogler}} herunder).
  • Samlet tabel med oversigt over alle argumenter til {{Wikidata-emne}}, {{Wikidata-tid}}, {{Wikidata-tal}}, {{Wikidata-streng}}, {{Wikidata-tekst}}.
  • Nyt filter til skabelonargumenter så headere til afsnit uden indhold kan filtreres fra i infobokse uden at gentage alle kald af Wikidata-skabelonerne. Det er besværligt, en kilde til fejl, og spilder tid. (Eksempel: {{Infoboks virksomhed}})
  • Reducering af antal artikler i Kategori:Oplysninger fra Wikidata på et andet sprog end dansk. Relevante Wikidata-emner uden dansk label kan findes med SPARQL. Eksempel for fødested nederst på siden. Koden kan tilpasses efter behov for andre egenskaber.
  • Optimering af Modul:Cycling race så cykelsportssider kan vises på en rimelig tid.
  • Optimering af Modul:Brug Wikidata (undgå at hente entiteter, flyt konfiguration og konstante tabeller til undermodul som kun skal indlæses en gang pr. side).
  • Bedre håndtering af referencer i Modul:Brug Wikidata.
  • Optimering af Modul:External links (giver timeout på siden Usain Bolt – gigantisk Wikidata-entitet med samtlige(?) konkurrencer han har deltaget i).
  • Hjælp:Søgning er stærk forældet, mangelfuld og indeholder direkte forkerte oplysninger. Mulighederne i Cirrus bør forklares.

Kategorier og specialsider mv. af interesse[redigér | rediger kildetekst]

# Steder som ikke har dansk label, hvor personer med en artikel på dawiki fødtes eller døde 
SELECT DISTINCT ?place ?placeLabel ?countryLabel
WHERE {
  ?person wdt:P19|wdt:P20 ?place.
  ?article schema:about ?person;
           schema:inLanguage 'da'.
  OPTIONAL { ?place wdt:P17 ?country. }
  OPTIONAL { ?place rdfs:label ?label.
             FILTER(LANG(?label) = "da") }
  FILTER(IF(BOUND(?label),false,true))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da","nb","nn","sv","en" }
}
ORDER BY ?countryLabel

Prøv det! 

# Steder hvor personer med en artikel på dawiki fødtes eller døde 
SELECT DISTINCT ?place
WHERE {
  ?person wdt:P19|wdt:P20 ?place.
  ?article schema:about ?person;
           schema:inLanguage 'da'.
# ?place wdt:P17 wd:Q30.  # Fra et bestemt land ...
}

Prøv det! 

# Noget uden dansk label, som en film med en artikel på dawiki er baseret på
SELECT DISTINCT ?article ?film ?filmLabel ?work ?workLabel
WHERE {
  ?film wdt:P31/wdt:P279* wd:Q11424.
  ?article schema:about ?film;
           schema:inLanguage 'da'.
  ?film wdt:P144 ?work
  OPTIONAL { ?work rdfs:label ?label.
             FILTER(LANG(?label) = "da") }
  FILTER(IF(BOUND(?label),false,true))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da","nb","nn","sv","en" }
}

Prøv det! 

# Person/firma uden dansk label som har arbejdet med en film (som
# (instruktør, producent, manuskripforfatter, skuespiller, filmholdsmedlem, 
# komponist, fotograf, klipper, studie, distributør) med en artikel på dawiki 
SELECT DISTINCT ?article ?film ?filmLabel ?person ?personLabel
WHERE {
  ?film wdt:P31/wdt:P279* wd:Q11424.
  ?article schema:about ?film;
           schema:inLanguage 'da'.
  ?film wdt:P162
        ?person.
#       wdt:P57|wdt:P58|wdt:P162|wdt:P161|wdt:P3092|wdt:P86|wdt:P344|
#       wdt:P1040|wdt:P483|wdt:P750 ?person.
  OPTIONAL { ?person rdfs:label ?label.
             FILTER(LANG(?label) = "da") }
  FILTER(IF(BOUND(?label),false,true))
  SERVICE wikibase:label
          { bd:serviceParam wikibase:language "da","nb","nn","sv","en" }
}

Prøv det! 

# Kønsfordeling for personer med artikler på dawiki
SELECT ?køn ?label (COUNT(?item) AS ?antal)
WHERE {
    ?item wdt:P31 wd:Q5; 
          wdt:P21 ?gender.
    ?link schema:about ?item;
          schema:isPartOf <https://da.wikipedia.org/>.
    OPTIONAL {
        ?gender rdfs:label ?genderLabel.
        FILTER(LANG(?genderLabel)="da").
    }
    BIND(IF(isBLANK(?gender),"(ukendt)",?gender) AS ?køn)
    BIND(IF(isBLANK(?gender),"(ukendt)",?genderLabel) AS ?label)
}
GROUP BY ?køn ?label
ORDER BY DESC(?antal)

Prøv det! 

# Artikler med taksoner med stort bogstav efter mellemrum
SELECT ?item ?link ?str
WHERE {
    ?item wdt:P31 wd:Q16521.
    ?link schema:about ?item;
          schema:isPartOf <https://da.wikipedia.org/>.
    FILTER(REGEX(STR(?link), "_[A-ZÆØÅ]"))
    BIND(STR(?link) AS ?str)
}

Prøv det! 

# Øer som ligger i søer med artikel på dansk 
SELECT DISTINCT ?island ?islandLabel ?lake ?lakeLabel ?link
WHERE {
  ?island wdt:P206 ?lake.
  ?island wdt:P31/wdt:P279* wd:Q23442.
  ?lake wdt:P31/wdt:P279* wd:Q23397.
  ?link schema:about ?island;
        schema:isPartOf <https://da.wikipedia.org/>.
  SERVICE wikibase:label
          { bd:serviceParam wikibase:language "da","nb","nn","sv","en" }
}

Prøv det! 

# Artikler som er i en kategori på et andet sprog men på ikke på dansk
SELECT ?item ?article ?title ?found_in
WITH
{
  SELECT 
    ?item
    (GROUP_CONCAT(?endpoint; SEPARATOR=", ") AS ?found_in)
    (MAX(?in_category) AS ?already_in_category)
  WHERE
  {
    ?category schema:name "Kategori:Søskende"@da .
    ?category schema:isPartOf <https://da.wikipedia.org/> .
    ?category schema:about ?category_item .
    ?other_cat schema:about ?category_item .
    ?other_cat schema:isPartOf ?wikimedia_site .
    ?other_cat schema:name ?category_title .
    BIND (STRBEFORE(STRAFTER(STR(?wikimedia_site), "https://"), "/") AS ?endpoint)
    OPTIONAL
    {
      SERVICE wikibase:mwapi
      {
        bd:serviceParam wikibase:endpoint ?endpoint .
        bd:serviceParam wikibase:api "Generator" .
        bd:serviceParam mwapi:generator "categorymembers" .
        bd:serviceParam mwapi:gcmtitle ?category_title .
        bd:serviceParam mwapi:gcmlimit "max" .
        ?item wikibase:apiOutputItem mwapi:item .
      }
    }
    FILTER BOUND (?item)
    BIND (IF(?wikimedia_site = <https://da.wikipedia.org/>, 1, 0) AS ?in_category)
  }
  GROUP BY ?item
  HAVING (?already_in_category = 0)
} AS %get_items
WHERE
{
  hint:Query hint:optimizer "None" .
  INCLUDE %get_items
  ?article schema:about ?item .
  ?article schema:isPartOf <https://da.wikipedia.org/> .
  ?article schema:name ?title .
}

Prøv det!

<mapframe>: Couldn't parse JSON: Control character error, possibly incorrectly encoded
Hentet fra "https://da.wikipedia.org/w/index.php?title=Bruger:Dipsacus_fullonum&oldid=11740277"