Skabelon:Tjk sync wd kategori for født

SELECT ?item ?artikel ?titel ?født
WITH
{
  SELECT ?item
  WHERE
  {
    SERVICE wikibase:mwapi {
	  bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "da.wikipedia.org" .
      bd:serviceParam mwapi:gcmtitle "Kategori:Født i 1980" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "page" .
      bd:serviceParam mwapi:gcmlimit "max" .
      ?item wikibase:apiOutputItem mwapi:item.
    }
  }
} AS %mwapi
WHERE
{
  ?item wdt:P31 wd:Q5 . # Udkommenteringen af denne linje for at finde andet end mennesker - dyr og fiktive personer
  ?artikel schema:isPartOf <https://da.wikipedia.org/> .
  ?artikel schema:about ?item .
  ?artikel schema:name ?titel.
  ?item wdt:P569 ?født . hint:Prior hint:rangeSafe true .
  FILTER (?født >= "1980-01-01T00:00:00Z"^^xsd:dateTime && ?født < "1981-01-01T00:00:00Z"^^xsd:dateTime)
  MINUS
  {
    INCLUDE %mwapi
  }
}

Tjek sync med wikidata

Skabelondokumentation[vis] [redigér] [historik] [opfrisk]

Skabelon, som har indeholder SPARQL forespørgsel, som bruges til at tjekke om udsavn fødselsdato (P569) i Wikidata, med Kategori:Født i <år>.

Brug

{{tjk sync wd kategori for født|<år>}}

Se også

• {{Tjk sync wd kategori for døde}}
• {{fødtår}}
• Bruger:Steenth/lister/wikidata/forskel imellem fødselsdato i wikidata og kategori i artikel
• Bruger:Steenth/lister/wikidata/har fødselsdato ukendt i artikel